Join the Discussion "Post your views, comments, questions and doubts to this article." Discuss!

Related Resources • How to create an Internet Shortcut (.URL) file • Working with Registry • VCL using tips • Text file IO

Elsewhere on the Web • Why not Registry? • 64K section limit

The .INI files have a text-based file format for representing application configuration data in a format which is easily editable by humans and readable by a simple automatic parser.

Most people who use Windows have at least a passing acquaintance with .INI files and with the WIN.INI and SYSTEM.INI files in particular (check your Windows directory). Windows stored (and still does) such important information as configuration information about Windows in plain text files that are easily deleted, modified or viewed.
Even though, in 32-bit Windows Microsoft recommends using Registry to store application specific configuration data, in many cases you'll find that using INI files is much faster and safer.

One simple use of INI files, as a status saving mechanism, would be to save the size and location of a form if you want a form to reappear at it's previous position. In general everything you store in Registry you could store in an INI file.

   .INI file format
Initialization or Configuration Settings file (.INI) is a text file with 64Kb limit divided into sections, each containing zero or more keys. Each key contains zero or more values. Example:

[SectionName]
keyname=value
;comment
keyname=value

Section names are enclosed in square brackets, and must begin at the beginning of a line. Section and key names are case-insensitive, and cannot contain spacing characters. The key name is followed by an equal sign ("="), optionally surrounded by spacing characters, which are ignored.
If the same section appears more than once in the same file, or if the same key appears more than once in the same section, then the last occurrence prevails.
A key can contain string, integer or boolean value.

Delphi uses INI file format in many cases. For example, the .DSK files (desktop settings) have a file format as described above.

   TIniFile
Delphi provides the TIniFile class with methods designed to store and retrieve application-specific information and settings from INI files. The TIniFile class is declared in the inifiles.pas unit. Prior to working with the TIniFile control you need to create an instance of the class:

uses inifiles;
...
var
  IniFile : TIniFile;
begin
  IniFile := TIniFile.Create('myapp.ini');

This code creates an IniFile object and assigns 'myapp.ini' to the only property of the class - the FileName property - used to specify the name of the INI file you are to use.
The code as written above looks (stores) for the myapp.ini file in the \Windows directory. A better way to store application data is in the application's folder - just specify the full path name of the file for the Create method:

// place the INI in the application folder, 
// let it have the application name 
// and 'ini' for extension:
  IniFile := TIniFile.Create(ChangeFileExt(
             Application.ExeName,'.ini'));

Reading
The TIniFile class has several "read" methods. The ReadString reads a string value from a key, ReadInteger, ReadFloat and similiar are used to read a number from a key. All "read" methods have a default value that can be used if the entry does not exist. For example the ReadString is declared as: function ReadString(const Section, Ident, Default: String): String; override;

Writing
The TIniFile has a corresponding "write" method for each "read" method. In other words they are WriteString, WriteBool, WriteInteger, etc.

procedure TForm1.FormCreate(Sender: TObject);
var
  IniFile  : TIniFile;
  LastUser : string;
  LastDate : TDateTime;
begin
  IniFile := TIniFile.Create(
             ChangeFileExt(Application.ExeName,'.ini'));

  //if no last user return an empty string
  LastUser := IniFile.ReadString('User','Last','');
  //if no last date return todays date
  LastDate := IniFile.ReadDate('User', 'Date', Date);

  //show the message
  ShowMessage('This program was previously used by '
              + LastUser + ' on '
              + DateToStr(LastDate));

  Form1.Top := IniFile.ReadInteger
               ('Placement','Top', Form1.Top);
  Form1.Left := IniFile.ReadInteger
                ('Placement','Left', Form1.Left);
  Form1.Width := IniFile.ReadInteger
                 ('Placement','Width', Form1.Width);
  Form1.Height := IniFile.ReadInteger
                  ('Placement','Height', Form1.Height);

  IniFile.Free;
end;

procedure TForm1.FormClose
           (Sender: TObject; var Action: TCloseAction);
var
  IniFile  : TIniFile;
begin
  IniFile := TIniFile.Create(
             ChangeFileExt(Application.ExeName,'.ini'));

  IniFile.WriteString('User','Last','Zarko Gajic');
  IniFile.WriteDate('User', 'Date', Date);

  With IniFile, Form1 do
  begin
    WriteInteger('Placement','Top', Top);
    WriteInteger('Placement','Left', Left);
    WriteInteger('Placement','Width', Width);
    WriteInteger('Placement','Height', Height);
  end;

  IniFile.Free;
end;

That's it. I hope you'll think twice the next time you ask yourself "where should I store my application's data". Anyway if you have any questions or comments to this article, feel free to post them on the Delphi Programming Forum.